重映射按键 (键盘, 鼠标和操纵杆)

简介

限制: 下面描述的 AutoHotkey 重映射功能通常不如直接通过 Windows 注册表进行映射那么直接有效. 对于每种方法的优点和缺点, 请参阅注册表重映射.

重映射键盘和鼠标

内置重映射功能的语法为 OriginKey::DestinationKey. 例如, 只包含下面这行内容的脚本会将 A 重映射成 B:

a::b

上面的例子没有改变 B 自身的功能. B 会继续发送 "b" 的键击, 除非把它重映射成其他功能, 就像下面例子中演示的那样:

a::b
b::a

上述例子中使用小写字母, 在大多数情况下建议这么做, 因为它也会映射相应的大写字母(即在 CapsLock 打开或 Shift 被按住时会发送大写形式). 与之相比, 在右边使用大写字母会强制发送大写形式. 例如, 下面的代码行在您输入 "a" 或 "A" 时都会产生大写字母 B(只要 CapsLock 是关闭的):

a::B

然而, 与上面相反的映射将不会像人们所期望的那样工作, 因为一个重新映射从来不会 "释放" 用来触发它的修饰符键. 例如, A::b 通常相当于 A::B 和 ^a::b 相当于 ^a::^b. 这是因为每个重映射在内部使用 {Blind} 来允许键或键组合与其他修饰符组合在一起.

鼠标重映射

要映射鼠标为键盘, 请使用和映射键盘相同的方法. 例如:

示例	描述
`MButton::Shift`	把鼠标中键映射成 `Shift`.
`XButton1::LButton`	把第四个鼠标按钮映射成鼠标左键.
`RAlt::RButton`	把右 `Alt` 映射成鼠标右键.

其他有用的映射

示例	描述
`CapsLock::Ctrl`	把 `CapsLock` 映射成 `Ctrl`. 要保留打开及关闭 `CapsLock` 的功能, 需先包含重映射 `+CapsLock::CapsLock`. 这样, 当按住 `Shift` 并点击 Capslock 时, 可切换 `CpasLock` 的开关状态. 因为两个重映射均允许附加修饰键被按下, 额外指定的 `+CapsLock::CapsLock` 重映射须优先放置.
`XButton2::^LButton`	把第五个鼠标按钮(XButton2) 映射成 Control-LeftClick.
`RAlt::AppsKey`	把右 `Alt` 映射成 `Menu`(这是打开上下文菜单的按键).
`RCtrl::RWin`	把右 `Ctrl` 映射成右 `Win`.
`Ctrl::Alt`	把左右 `Ctrl` 映射成 `Alt`. 但是, 请参阅 alt-tab 的问题.
`^x::^c`	把 `Ctrl`+`X` 映射成 `Ctrl`+`C`. 它也会让 `Ctrl`+`Alt`+`X` 产生 `Ctrl`+`Alt`+`C`, 等等.
RWin::Return	禁用右 `Win`, 通过简单地执行 return.

您可以尝试执行这里的每个例子: 把它们复制到新文本文件(例如 "Remap.ahk"), 然后运行这个文件.

请参阅按键列表来了解按键和鼠标按钮名称的完整列表.

备注

使用 #IfWinActive/Exist 指令可以让重映射仅在指定的窗口中有效. 例如:

#IfWinActive ahk_class Notepad
a::b  ; 让 'a' 键到 'b' 键的映射仅在记事本中有效.
#IfWinActive  ; 这里让后续的重映射和热键对所有窗口生效.

重映射按键和鼠标按钮在下面的关系中是 "完整的":

按住修饰符(例如 Ctrl 或 Shift) 后按下原始键, 会让那个修饰符对目标键生效. 例如, b::a 会在您按下 Ctrl+B 时产生 Ctrl+A 的效果.
CapsLock 通常会像普通键那样影响重映射的按键.
按住目标键或按钮的时间和您持续按住原始键的时间一样长. 但是, 一些游戏不支持重映射; 此时, 键盘和鼠标的重映射没有效果.
按住被重映射的按键时, 它们的目标键会自动重复(除非是把按键重映射为鼠标按钮).

尽管被重映射的按键可以触发普通热键, 但默认情况下它不能触发鼠标热键或钩子热键(请使用 ListHotkeys 来找出哪些热键使用了钩子). 例如, 如果重映射 a::b 有效, 那么按下 Ctrl+Alt+A 会触发 ^!b 热键, 但仅在 ^!b 不是钩子热键的时候. 如果 ^!b 是钩子热键, 而且您希望使用 Ctrl+Alt+A 来执行和 Ctrl+Alt+B 相同的动作, 那么您可以把 ^!a 定义为热键. 例如:

a::b
^!a::
^!b::
ToolTip You pressed %A_ThisHotkey%.
return

在 [v1.1.06] 及更高版本中, 还可使用 #InputLevel 来覆盖此默认行为. 例如:

#InputLevel 1
a::b

#InputLevel 0
^!b::
ToolTip You pressed %A_ThisHotkey%.
return

如果在自动运行段(脚本的顶部) 使用了 SendMode, 那么它会影响所有的重映射. 但是, 由于重映射使用 Send {Blind} 而 SendPlay 模式不完全支持 {Blind}, 所以一些映射在 SendPlay 模式中可能无法正常运行(尤其是 Ctrl, Shift, Alt 和 Win). 要变通解决此问题, 当您脚本中含有重映射时请避免在自动执行段中使用 SendPlay; 而仅在整个脚本的一些需要的地方使用 SendPlay 命令而不是 Send. 或者, 您可以把您的重映射转换为热键(如下所述), 这样就明确调用 SendEvent 而不是 Send.

加载脚本时, 每个重映射会被转换为一对热键. 例如, 包含重映射 a::b 的脚本实际包含下面的两个热键:

*a::
SetKeyDelay -1   ; 如果目标键是鼠标按钮, 则使用 SetMouseDelay 代替.
Send {Blind}{b DownR}  ; DownR 和 Down 相似, 不过使用 DownTemp 时脚本中后面的其他 Send 命令则不会假定 "b" 仍然处于按下的状态.
return

*a up::
SetKeyDelay -1  ; 请参阅下面的注意事项来了解在这段代码中两处 SetKeyDelay 都没有指定按键时长的原因.
Send {Blind}{b up}
return

但是, 上面的两个热键在下列环境中会发生变化:

当原始键为左 Ctrl 而目标键为 Alt 时, 会把 Send {Blind}{LAlt DownR} 这行语句替换为 Send {Blind}{LCtrl up}{LAlt DownR}. 如果原始键为右 Ctrl 也会如此, 除非使用了 {RCtrl up}.
当键盘按键被重映射为鼠标按钮时(例如 RCtrl::RButton), 在上面的热键中会使用 SetMouseDelay 代替 SetKeyDelay. 而且, 上面的首个热键会被替换为下面的热键, 这样避免了由于键盘的自动重复功能生成的重复的鼠标点击:
```
*RCtrl::
SetMouseDelay -1
if not GetKeyState("RButton")  ; 即鼠标右键还没有按下.
    Send {Blind}{RButton DownR}
return
```
当源代码是 [v1.1.27.01+] 中的自定义组合键时, 通配符修饰符(*) 被省略以允许热键工作.

在 [v1.1.27] 之前, 使用 DownTemp 而不是 DownR.

请注意在上面的热键中省略了 SetKeyDelay 的第二个参数(按键时长). 这是因为按键时长不适用于独立的按键按下或按键弹起事件, 例如 {b down} 和 {b up}. 但是, 它适用于修饰键(Shift, Ctrl, Alt 和 Win) 状态的改变, 这会影响像 a::B 或 a::^b 的重映射. 因此, 脚本中任何在自动执行段生效的按键时长会应用于所有这类重映射.

由于重映射会被简单翻译为上面描述的热键, 所以 Suspend 也会影响它们. 同样地, Hotkey 命令可以禁用或修改重映射. 例如, 下面的两个命令会禁用重映射 a::b.

Hotkey, *a, Off
Hotkey, *a up, Off

Alt-tab 的问题: 如果您把一个按键或鼠标按钮映射为 Alt, 那么这个键很可能无法正确实现 alt-tab 的功能. 一个可能的变通解决方法是添加热键 *Tab::Send {Blind}{Tab}, 但是需要注意这样很可能妨碍使用真正的 Alt 实现 alt-tab 的功能. 因此, 这种方法只应当用于在您希望单独使用重映射的按键和/或 alt-tab 热键实现 alt-tab 功能的时候.

除了按键列表页面中的按键和鼠标按钮, 原始键还可以是在特殊按键页面描述的虚拟键(VKnn) 或扫描码(SCnnn). 对于目标键同样如此, 不过它还可以在虚拟键后指定扫描码. 例如, 在大多数键盘布局中 sc01e::vk42sc030 相当于 a::b.

要禁用按键而不进行重映射, 请把它设置为只含有 return 的热键. 例如,F1::return 会禁用 F1.

内置的重映射功能不支持下列键:

鼠标滚轮(WheelUp/Down/Left/Right).
Pause 和 Break 不能作为目标键(因为它们会被作为命令执行).
大括号 {} 不能作为目标键. 作为替代请使用 VK/SC 方法; 例如 x::+sc01A 和 y::+sc01B.
百分号(%) 不能作为目标键. 作为替代请使用 VK/SC 方法.
"Return" 不能作为目标键. 作为替代请使用 "Enter".

通过键盘移动鼠标光标

如同在全功能键盘到鼠标的映射脚本中演示的那样, 可以使用键盘来移动鼠标光标. 由于这个脚本提供了鼠标平滑移动, 加速和其他功能, 所以如果您想使用键盘实现许多的鼠标操作, 推荐您使用这个脚本. 与之相比, 下面的例子只是简化的演示:

*#up::MouseMove, 0, -10, 0, R  ; Win+UpArrow 热键 => 上移光标
*#Down::MouseMove, 0, 10, 0, R  ; Win+DownArrow => 下移光标
*#Left::MouseMove, -10, 0, 0, R  ; Win+LeftArrow => 左移光标
*#Right::MouseMove, 10, 0, 0, R  ; Win+RightArrow => 右移光标

*<#RCtrl::  ; LeftWin + RightControl => Left-click (按住 Control/Shift 来进行 Control-Click 或 Shift-Click).
SendEvent {Blind}{LButton down}
KeyWait RCtrl  ; 防止键盘自动重复导致的重复鼠标点击.
SendEvent {Blind}{LButton up}
return

*<#AppsKey::  ; LeftWin + AppsKey => Right-click
SendEvent {Blind}{RButton down}
KeyWait AppsKey  ; 防止键盘自动重复导致重复的鼠标点击.
SendEvent {Blind}{RButton up}
return

使用注册表的 "扫描码映射" 功能进行重映射

优点:

注册表的重映射功能通常比 AutoHotkey 的重映射更加直接有效. 例如, 它能适应于更大范围的游戏, 它不存在 alt-tab 问题, 并且它能触发 AutoHotkey 的钩子热键(然而 AutoHotkey 的重映射需要间接的方法才行).
如果您会手动修改注册表条目(下面进行阐述), 那么不需要任何外部软件就可以重映射您的键盘. 即使您使用 KeyTweak 来修改注册表条目, 那么完成后 KeyTweak 不需要一直保持运行(而 AutoHotkey 需要一直运行, 重映射才会生效).

缺点:

注册表重映射比较不灵活: 每次修改映射都必须重启后才会生效.
效果是全局的: 它不能创建针对特定用户, 应用程序或环境的重映射.
它无法发送含修饰键 Shift, Ctrl, Alt 或 AltGr 的组合键. 例如, 它不能把小写字符映射为大写字符.
它只支持键盘(AutoHotkey 还支持鼠标重映射和一些受限的操纵杆重映射).

如何修改注册表: 使用注册表重映射按键至少有两种方法:

使用像 KeyTweak(免费软件) 这样的程序在可视界面中重映射按键. 它会自动修改注册表.
手动创建重映射按键的 .reg 文件(纯文本) 并把它载入注册表. 演示的例子请参阅 www.autohotkey.com/forum/post-56216.html#56216

dftg