WinGetControls

返回指定窗口中所有控件的名称.

Controls := WinGetControls(WinTitle, WinText, ExcludeTitle, ExcludeText)

参数

WinTitle

类型: 字符串, 整数或对象

识别目标窗口的窗口标题或其他条件. 请参阅 WinTitle.

WinText

类型: 字符串

如果存在, 此参数必须是目标窗口的单个文本元素的子字符串(和内置的 Window Spy 工具显示的一样). 如果 DetectHiddenText 为 ON, 那么会检测隐藏文本元素.

ExcludeTitle

类型: 字符串

标题中含有此参数值的窗口将被排除.

ExcludeText

类型: 字符串

文本中含有此参数值的窗口将被排除.

返回值

类型: 数组

此函数返回一个包含指定窗口中所有控件的名称的数组. 每个控件名称由它的类名紧跟着它的序号(ClassNN), 如 Window Spy 所示. 如果没有匹配的窗口, 则返回一个空字符串.

例如, 如果将返回值赋值给名为 Controls 的变量, 并且存在两个控件, 则 Controls[1] 包含第一个控件的名称, Controls[2] 包含第二个控件的名称, 而 Controls.Length 返回该数字 2.

控件是按照 Z 轴顺序排序的, 如果窗口支持 Tab 键, Z 轴顺序通常与通过 Tab 导航的顺序相同.

错误处理

如果找不到窗口, 则抛出 TargetError.

备注

鼠标光标下的窗口或控件的 ID 可以使用 MouseGetPos 来获取.

窗口标题和文本是区分大小写的. 除非 DetectHiddenWindows 被打开, 否则不会检测隐藏窗口.

相关

WinGetControlsHwnd, Win 函数, Control 函数

示例

for n, ctrl in WinGetControls("A")
{
    Result := MsgBox("Control #" n " is '" ctrl "'. Continue?",, 4)
    if (Result = "No")
        break
}

SetTimer WatchActiveWindow, 200

WatchActiveWindow()
{
    try
    {
        Controls := WinGetControls("A")
        ControlList := ""
        for ClassNN in Controls
            ControlList .= ClassNN . "`n"
        if (ControlList = "")
            ToolTip "The active window has no controls."
        else
            ToolTip ControlList
    }
    catch TargetError
        ToolTip "No visible window is active."
}