StrSplit

使用指定的分隔符将字符串分成子字符串数组.

Array := StrSplit(String , Delimiters, OmitChars, MaxParts)

参数

String

类型: 字符串

要分割的字符串.

Delimiters

类型: 字符串

如果此参数为空或省略, 那么将把输入字符串中的每个字符解析为单独的子字符串.

否则, Delimiters 可以是单个字符串, 也可以是字符串数组, 每个分隔符用于确定子字符串之间的边界出现的位置. 由于分隔符不被视为子字符串本身的一部分, 因此它们决不会包含在返回的数组中. 同样, 如果输入字符串中的一对定界符之间没有任何内容, 则对应的数组元素将为空.

例如: "," 将根据逗号每次出现的位置分割字符串. 同样地, 使用 [A_Tab, A_Space] 作为分隔符将在输入字符串中每次遇到空格或制表符时创建一个新的数组元素.

OmitChars

类型: 字符串

可选的字符列表(区分大小写), 用来从每个数组元素的开始和结尾部分移除这些字符. 例如, 如果 OmitChars 是 " `t", 那么每个元素中开始和结尾部分(但中间的不会) 的空格和制表符会被移除.

如果 Delimiters 为空, 那么 OmitChars 表示需要从数组中排除的那些字符.

MaxParts

类型: 整数

如果省略, 则默认为 -1, 表示 "没有限制". 否则, 请指定返回的子字符串的最大数目. 如果非零, 则字符串最多被分割 MaxParts-1 次, 并且在最后一个子字符串中返回字符串的其余部分(不包括任何前导或尾随的 OmitChars).

返回值

类型: 数组

函数返回一个包含指定字符串的子字符串的数组.

备注

除非空格和制表符之类的空白字符包含在 Delimiters 或 OmitChars 参数中, 否则它们将被保留. 可以使用 Trim 从任何变量的两端移除制表符和空格. 例如: Var := Trim(Var)

要拆分标准 CSV(逗号分隔值) 格式的字符串, 请使用解析循环, 因为它具有内置 CSV 处理功能.

要在分割前按不同的顺序排列字段, 请使用 Sort 函数.

如果您不需要把子字符串长时间的存储到内存中, 建议使用解析循环 -- 尤其在 String 非常大时可以节约大量内存. 例如:

Colors := "red,green,blue"
Loop Parse, Colors, ","
    MsgBox "Color number " A_Index " is " A_LoopField

相关

Parsing loop, Sort, SplitPath, InStr, SubStr, StrLen, StrLower, StrUpper, StrReplace

示例

TestString := "This is a test."
word_array := StrSplit(TestString, A_Space, ".")  ; 忽略句点.
MsgBox "The 4th word is " word_array[4]

colors := "red,green,blue"
For index, color in StrSplit(colors, ",")
    MsgBox "Color number " index " is " color