MsgBox

在含有一个或多个按钮(例如 "是" 和 "否") 的小窗口中显示指定的文本.

MsgBox Text, Title, Options
Result := MsgBox(Text, Title, Options)

参数

Text

类型: 字符串

如果省略所有的参数, 则消息框会显示 "Press OK to continue.". 否则, 此参数表示消息框中显示的文本, 用来引导用户如何操作或提示信息.

可以使用转义序列来表示特殊字符. 例如, `n 表示换行符, 它结束当前行并开始一个新行. 因此, 使用 text1`n`ntext2 会在 text1 和 text2 之间添加一个空行.

如果 Text 较长, 可以通过延续片段的方法将其分解成较短的几行, 这样可以增加可读性和可维护性.

Title

类型: 字符串

消息框窗口的标题. 如果省略, 那么它默认为 A_ScriptName 的当前值.

Options

类型: 字符串

表示消息框的类型和可能的按钮组合. 如果为空或省略, 则默认为 0. 请参阅下面的表格来了解允许的值.

此外, 还可以指定以下零个或多个选项:

Owner: 要为消息框指定所有者窗口, 请使用单词 Owner 后接 HWND(窗口 ID).

T: 超时. 如果用户在指定的时间内没有关闭消息框, 要让消息框自动关闭, 请使用字母 T 后接超时秒数, 可以包含小数点. 如果这个值超过 2147483(24.8 天), 将被设置为 2147483. 如果消息框超时, 返回值为单词 Timeout.

Options 参数的值

Options 参数可以是以下组的数字值的组合(和), 这些值直接传递给操作系统的 MessageBox 函数, 也可以是由至少一个空格或制表符分隔的不区分大小写的选项组成的字符串. 字符串中还可以包含一个或多个数字选项.

组 #1: 按钮

若要指定在消息框中显示的按钮, 请添加以下值之一:

组 #2: 图标

要在消息框中显示一个图标, 请添加以下值之一:

组 #3: 默认按钮

若要指定默认按钮, 请添加以下值之一:

组 #4: 模式

若要指定对话框的模式, 请添加以下值之一:

组 #5: 其他选项

若要指定其他选项, 请添加以下值中的一个或多个:

返回值

类型: 字符串

当从一个表达式中调用时, MsgBox 返回以下字符串中的一个来表示用户按下了哪个按钮:

• OK
• Cancel
• Yes
• No
• Abort
• Retry
• Ignore
• TryAgain
• Continue
• Timeout(即, 如果消息框超时, 则返回单词 "timeout")

备注

消息框通常看起来像这样:

要确定用户按下了哪个按钮, 请使用函数的返回值. 例如:

Result := MsgBox("Would you like to continue? (press Yes or No)",, "YesNo")
if Result = "Yes"
    MsgBox "You pressed Yes."
else
    MsgBox "You pressed No."

if MsgBox("Retry or cancel?",, "R/C") = "Retry"
    MsgBox("You pressed Retry.")

参照这个示例可以自定义按钮的名称.

提示: 当消息框窗口处于活动状态时, 按下 Ctrl+C 将复制其中的文本到剪贴板. 这适用于所有的消息框, 而不仅是 AutoHotkey 生成的那些.

GUI 窗口当作 MsgBox: 通过使用 OwnDialogs 选项的方法 GUI 窗口可以显示为 modal(模式) 消息框. 模式 消息框在其消失之前会阻止用户与原来的 GUI 窗口进行交互. 此时, 不需要指定上表中的系统模式或任务模式选项.

当 OwnDialogs 选项 无效 时, 任务模式选项(8192) 可用于禁用所有脚本的窗口, 直到用户取消消息框.

如果指定了 OwnerHWND 选项, 它将优先于任何其他设置. HWND 可以是任何窗口的 HWND, 即使不是脚本所拥有的窗口.

帮助按钮: 在 Options 中使用了帮助按钮选项(16384) 时, 只有符合下面两个条件, 那么按下帮助按钮才会有效果:

1. 消息框是使用 OwnDialogs 选项的方法为 Gui 窗口所有.
2. 脚本正在监控 WM_HELP 消息(0x0053). 例如: OnMessage(0x0053, "WM_HELP"). 当 WM_HELP 函数被调用时, 可能会通过诸如显示另一个窗口或消息框等方式引导用户.

关闭按钮(在消息框的标题栏): 由于消息框窗口是操作系统内置的特性, 所以它的 X 按钮只有在某些按钮存在时才会被启用. 如果只有一个 OK(确认) 按钮, 点击 X 按钮等同于点击 OK 按钮. 否则, X 按钮将被禁用, 除非有一个取消按钮, 在这种情况下, 点击 X 按钮就等同于按下取消.

相关

InputBox, FileSelect, DirSelect, ToolTip, Gui 对象

示例

MsgBox "This is a string."

MsgBox "This MsgBox has a custom title.", "A Custom Title"

MsgBox ; "Press OK to continue."

MsgBox "
  (
    第一个参数显示为信息.
    第二个参数成为窗口标题.
    第三个参数决定了消息框的类型.
  )", "Window Title", "iconi"

result := MsgBox("Do you want to continue? (Press YES or NO)",, "YesNo")
if (result = "No")
    return

result := MsgBox("This MsgBox will time out in 5 seconds.  Continue?",, "Y/N T5")
if (result = "Timeout")
    MsgBox "You didn't press YES or NO within the 5-second period."
else if (result = "No")
    return

var := 10
MsgBox "The initial value is: " var
MsgBox "The result is: " var * 2
MsgBox Format("The result is: {1}", var * 2)