DllCall

调用 Windows API 函数 "MessageBox" 并报告用户按下了哪个按钮.

WhichButton := DllCall("MessageBox", "Int", 0, "Str", "Press Yes or No", "Str", "Title of box", "Int", 4)
MsgBox "You pressed button #" WhichButton

将桌面墙纸更改为指定的位图(.bmp) 文件.

DllCall("SystemParametersInfo", "UInt", 0x14, "UInt", 0, "Str", A_WinDir . "\winnt.bmp", "UInt", 1)

调用 API 函数 "IsWindowVisible" 来判断记事本窗口是否可见.

DetectHiddenWindows True
if not DllCall("IsWindowVisible", "Ptr", WinExist("Untitled - Notepad"))  ; WinExist 返回 HWND.
    MsgBox "The window is not visible."

调用 API 的 wsprintf() 函数来给数字 432 加上前导零以填充到 10 个字符的长度(0000000432).

ZeroPaddedNumber := Buffer(20)  ; 确保缓冲足够大以便容纳新的字符串.
DllCall("wsprintf", "Ptr", ZeroPaddedNumber, "Str", "%010d", "Int", 432, "Cdecl")  ; 需要 Cdecl 调用约定.
MsgBox StrGet(ZeroPaddedNumber)

; 此外, 使用 Format 函数配合 0 标志可以达到同样的效果:
MsgBox Format("{:010}", 432)

演示 QueryPerformanceCounter(), 它提供了比 A_TickCount 的 10 ms 更高的精确度.

DllCall("QueryPerformanceFrequency", "Int64*", &freq := 0)
DllCall("QueryPerformanceCounter", "Int64*", &CounterBefore := 0)
Sleep 1000
DllCall("QueryPerformanceCounter", "Int64*", &CounterAfter := 0)
MsgBox "Elapsed QPC time is " . (CounterAfter - CounterBefore) / freq * 1000 " ms"

按下热键临时减慢鼠标移动速度, 这样有助于准确定位. 按住 F1 来降低鼠标速度. 释放后则恢复原来的速度.

F1::
F1 up::
{
    static SPI_GETMOUSESPEED := 0x70
    static SPI_SETMOUSESPEED := 0x71
    static OrigMouseSpeed := 0

    switch ThisHotkey
    {
    case "F1":
        ; 获取鼠标当前的速度以便稍后恢复:
        DllCall("SystemParametersInfo", "UInt", SPI_GETMOUSESPEED, "UInt", 0, "Ptr*", OrigMouseSpeed, "UInt", 0)
        ; 现在在倒数第二个参数中设置较低的速度 (范围为 1-20, 10 是默认值):
        DllCall("SystemParametersInfo", "UInt", SPI_SETMOUSESPEED, "UInt", 0, "Ptr", 3, "UInt", 0)
        KeyWait "F1"  ; 这里避免了由于键盘的重复特性导致再次执行 DllCall.

    case "F1 up":
        DllCall("SystemParametersInfo", "UInt", SPI_SETMOUSESPEED, "UInt", 0, "Ptr", OrigMouseSpeed, "UInt", 0)  ; 恢复原始速度.
    }
}

监视活动窗口并显示其焦点控件中的垂直滚动条的位置(实时更新).

SetTimer WatchScrollBar, 100

WatchScrollBar()
{
    try FocusedHwnd := ControlGetFocus("A")
    if !FocusedHwnd  ; 没有焦点控件.
        return
    ; 在工具提示中显示垂直或水平滚动条的位置:
    ToolTip(DllCall("GetScrollPos", "Ptr", FocusedHwnd, "Int", 1))  ;  最后一个参数 1 表示 SB_VERT, 而 0 表示 SB_HORZ.
}

写入一些文本到文件, 然后从文件读取回内存. 在同时读取或写入多个文件时, 使用这种方法可以改善性能. 此外, 使用 FileOpen 可以实现同样的目的.

FileName := FileSelect("S16",, "Create a new file:")
if FileName = ""
    return
GENERIC_WRITE := 0x40000000  ; 以写入而不是读取的方式打开文件.
CREATE_ALWAYS := 2  ; 创建新文件(覆盖任何现有的文件).
hFile := DllCall("CreateFile", "Str", FileName, "UInt", GENERIC_WRITE, "UInt", 0, "Ptr", 0, "UInt", CREATE_ALWAYS, "UInt", 0, "Ptr", 0, "Ptr")
if !hFile
{
    MsgBox "Can't open '" FileName "' for writing."
    return
}
TestString := "This is a test string.`r`n"  ; 通过这种方式写入内容到文件时, 要使用 `r`n 而不是 `n 来开始新行.
StrSize := StrLen(TestString) * 2
DllCall("WriteFile", "Ptr", hFile, "Str", TestString, "UInt", StrSize, "UIntP", &BytesActuallyWritten := 0, "Ptr", 0)
DllCall("CloseHandle", "Ptr", hFile)  ; 关闭文件.

; 现在已经把内容写入文件了, 重新把它们读取回内存中.
GENERIC_READ := 0x80000000  ; 以读取而不是写入的方式来打开文件.
OPEN_EXISTING := 3  ; 此标志表示要打开的文件必须已经存在.
FILE_SHARE_READ := 0x1 ; 这个和下一个标志表示其他进程是否可以打开我们已经打开的文件.
FILE_SHARE_WRITE := 0x2
hFile := DllCall("CreateFile", "Str", FileName, "UInt", GENERIC_READ, "UInt", FILE_SHARE_READ|FILE_SHARE_WRITE, "Ptr", 0, "UInt", OPEN_EXISTING, "UInt", 0, "Ptr", 0)
if !hFile
{
    MsgBox "Can't open '" FileName "' for reading."
    return
}
; 为要读取的字符串分配一块内存:
Buf := Buffer(StrSize)
DllCall("ReadFile", "Ptr", hFile, "Ptr", Buf, "UInt", Buf.Size, "UIntP", &BytesActuallyRead := 0, "Ptr", 0)
DllCall("CloseHandle", "Ptr", hFile)  ; 关闭文件.
MsgBox "The following string was read from the file: " StrGet(Buf)

当您按下 Win+C 时, 隐藏鼠标光标. 稍后若要显示光标, 请再次按下热键.

OnExit (*) => SystemCursor("Show")  ; 确保到脚本退出时鼠标光标是显示的.

#c::SystemCursor("Toggle")  ; Win+C 热键用来切换鼠标光标的显示和隐藏.

SystemCursor(cmd)  ; cmd = "Show|Hide|Toggle|Reload"
{
    static visible := true, c := Map()
    static sys_cursors := [32512, 32513, 32514, 32515, 32516, 32642
                         , 32643, 32644, 32645, 32646, 32648, 32649, 32650]
    if (cmd = "Reload" or !c.Count)  ; 在请求或首次调用时进行重载.
    {
        for i, id in sys_cursors
        {
            h_cursor  := DllCall("LoadCursor", "Ptr", 0, "Ptr", id)
            h_default := DllCall("CopyImage", "Ptr", h_cursor, "UInt", 2
                , "Int", 0, "Int", 0, "UInt", 0)
            h_blank   := DllCall("CreateCursor", "Ptr", 0, "Int", 0, "Int", 0
                , "Int", 32, "Int", 32
                , "Ptr", Buffer(32*4, 0xFF)
                , "Ptr", Buffer(32*4, 0))
            c[id] := {default: h_default, blank: h_blank}
        }
    }
    switch cmd
    {
      case "Show": visible := true
      case "Hide": visible := false
      case "Toggle": visible := !visible
      default: return
    }
    for id, handles in c
    {
        h_cursor := DllCall("CopyImage"
            , "Ptr", visible ? handles.default : handles.blank
            , "UInt", 2, "Int", 0, "Int", 0, "UInt", 0)
        DllCall("SetSystemCursor", "Ptr", h_cursor, "UInt", id)
    }
}

结构的例子. 把 RECT 结构的地址传递给 GetWindowRect(), 它会把窗口的左, 上, 右和下边的位置(相对于屏幕) 存入结构的成员中.

Run "Notepad"
WinWait "Untitled - Notepad"  ; 这里同时设置了 "上次找到的窗口" 以用于下面的 WinExist.
Rect := Buffer(16)  ; RECT 结构由四个 32 位整数组成(即 4*4=16).
DllCall("GetWindowRect", "Ptr", WinExist(), "Ptr", Rect)  ; WinExist 返回 HWND.
L := NumGet(Rect, 0, "Int"), T := NumGet(Rect, 4, "Int")
R := NumGet(Rect, 8, "Int"), B := NumGet(Rect, 12, "Int")
MsgBox Format("Left {1} Top {2} Right {3} Bottom {4}", L, T, R, B)

Rect := Buffer(16)  ; 设置容量为 4 个 4 字节整型.
NumPut( "Int", 0                  ; 左
      , "Int", 0                  ; 上
      , "Int", A_ScreenWidth//2   ; 右
      , "Int", A_ScreenHeight//2  ; 下
      , Rect)
hDC := DllCall("GetDC", "Ptr", 0, "Ptr")  ; 传递零来获取桌面的设备上下文.
hBrush := DllCall("CreateSolidBrush", "UInt", 0x0000FF, "Ptr")  ; 创建红色画刷(0x0000FF 是 BGR 格式).
DllCall("FillRect", "Ptr", hDC, "Ptr", Rect, "Ptr", hBrush)  ; 使用上面的画刷填充指定的矩形.
DllCall("ReleaseDC", "Ptr", 0, "Ptr", hDC)  ; 清理.
DllCall("DeleteObject", "Ptr", hBrush)  ; 清理.

SetSystemTime("20051008142211")  ; 传递时间戳(本地的, 非 UTC).

SetSystemTime(YYYYMMDDHHMISS)
; 设置系统时钟为指定的日期和时间.
; 调用者必须确保传入的参数是有效的日期时间戳
; (本地时间, 非 UTC). 成功时返回非零值, 否则返回零.
{
    ; 把参数从本地时间转换为 UTC 以便用于 SetSystemTime().
    UTC_Delta := DateDiff(A_Now, A_NowUTC, "Seconds")  ; 取整后秒数会更精确.
    UTC_Delta := Round(-UTC_Delta/60)  ; 取整到最近的分钟数以确保精度.
    YYYYMMDDHHMISS := DateAdd(YYYYMMDDHHMISS, UTC_Delta, "Minutes")  ; 对本地时间应用偏移来转换到 UTC.

    SystemTime := Buffer(16)  ; 此结构由 8 个 UShort 组成(即 8*2=16).

    NumPut( "UShort", SubStr(YYYYMMDDHHMISS, 1, 4)  ; YYYY(年)
          , "UShort", SubStr(YYYYMMDDHHMISS, 5, 2)  ; MM(月, 01-12)
          , "UShort", 0                             ; Unused(周几)
          , "UShort", SubStr(YYYYMMDDHHMISS, 7, 2)  ; DD(日)
          , "UShort", SubStr(YYYYMMDDHHMISS, 9, 2)  ; HH(小时, 00-24)
          , "UShort", SubStr(YYYYMMDDHHMISS, 11, 2) ; MI(分钟)
          , "UShort", SubStr(YYYYMMDDHHMISS, 13, 2) ; SS(秒)
          , "UShort", 0                             ; Unused(毫秒)
          , SystemTime)

    return DllCall("SetSystemTime", "Ptr", SystemTime)
}

更多结构的例子:

• 请参阅 WinLIRC 客户端脚本演示来学习如何使用 DllCall 来创建 到 TCP/IP 服务器的连接并从那里接收数据.
• 操作系统提供了标准的对话框让用户选取字体和/或颜色或图标. 这些对话框使用了结构, 并可以在这里找到演示的例子: GitHub.

从任务栏移除活动窗口 3 秒. 可以对比一下等同效果的 ComCall 示例.

/*
  Methods in ITaskbarList's VTable:
    IUnknown:
      0 QueryInterface  -- 使用 ComObjQuery 代替
      1 AddRef          -- 使用 ObjAddRef 代替
      2 Release         -- 使用 ObjRelease 代替
    ITaskbarList:
      3 HrInit
      4 AddTab
      5 DeleteTab
      6 ActivateTab
      7 SetActiveAlt
*/
IID_ITaskbarList  := "{56FDF342-FD6D-11d0-958A-006097C9A090}"
CLSID_TaskbarList := "{56FDF344-FD6D-11d0-958A-006097C9A090}"

; 创建 TaskbarList 对象.
tbl := ComObject(CLSID_TaskbarList, IID_ITaskbarList)

activeHwnd := WinExist("A")

DllCall(vtable(tbl.ptr,3), "ptr", tbl)                     ; tbl.HrInit()
DllCall(vtable(tbl.ptr,5), "ptr", tbl, "ptr", activeHwnd)  ; tbl.DeleteTab(activeHwnd)
Sleep 3000
DllCall(vtable(tbl.ptr,4), "ptr", tbl, "ptr", activeHwnd)  ; tbl.AddTab(activeHwnd)

; 非包装接口指针必须手动释放.
ObjRelease(tbl.ptr)

vtable(ptr, n) {
    ; NumGet(ptr, "ptr") 返回对象的虚函数表(简称为 vtable) 的地址
    ; 表达式的其余部分从
    ; vtable 中获取第 n 个函数的地址.
    return NumGet(NumGet(ptr, "ptr"), n*A_PtrSize, "ptr")
}