# GroupAdd

增加窗口规格到窗口组, 必要时创建组.

    GroupAdd GroupName , WinTitle, WinText, ExcludeTitle, ExcludeText

## 参数

GroupName

  类型: 字符串

  要向其中添加此窗口规范的组的名称. 如果组不存在, 则会创建它. 组名不区分大小写.

WinTitle

  类型: 字符串, 整数或对象

  识别目标窗口的窗口标题或其他条件. 请参阅 WinTitle.

WinText

  类型: 字符串

  如果使用此参数, 那么它必须是目标窗口中单个文本元素的子字符串(和内置的 Window Spy 工具显示的一样). 如果在使用 GroupActivate, GroupDeactivate 和 GroupClose 时, DetectHiddenText 为 ON, 则会检测到隐藏的文本元素.

ExcludeTitle

  类型: 字符串

  标题中含有此参数值的窗口将被排除.

ExcludeText

  类型: 字符串

  文本中含有此参数值的窗口将被排除.

## 备注

每使用此函数一次则添加一条新规则到组中. 换句话说, 一个组由窗口规格的集合组成而不是固定的窗口列表. 后面当类似 GroupActivate的函数使用组时, 会使用这些规则中的每一条检查桌面上的每个窗口. 如果窗口匹配组里的其中一条规则, 则它被视为一个匹配.

尽管 SetTitleMatchMode 和 DetectHiddenWindows 不会直接影响此函数的行为, 但它们会影响其他组函数(例如 GroupActivate 和 GroupClose). 它们还会影响其他任何函数的 WinTitle 参数中 ahk_group 的使用.

窗口组的典型用法是将相关窗口收集绑定在一起, 这可用于包含许多相关窗口的任务或有许多子窗口的程序. 例如, 如果您频繁地工作在一个图形程序或文本编辑器的多个实例时, 您可以使用热键通过 GroupActivate 来切换此程序的每一个实例(每次一个), 而不需要使用 alt-tab 或任务栏按钮找到它们.

由于每组中的条目仅需要添加一次, 所以此函数通常使用在脚本启动时. 添加重复的条目到组中会被忽略.

要在一个组中包含 所有 窗口(除了特殊的 Program Manager 窗口), 请使用这个例子:

    GroupAdd "AllWindows"

通过在 WinTitle 参数中指定 `ahk_group MyGroupName`, 所有的窗口函数都可以操作窗口组. 函数 WinMinimize, WinMaximize, WinRestore, WinHide, WinShow, WinClose 和 WinKill 会对一个组中的 所有 窗口进行操作. 要仅对顶层窗口进行操作, 请参照此例:

    WinHide WinExist("ahk_group MyGroup")

与之相比, 其他的窗口函数(例如 WinActivate 和 WinExist) 只对组中的顶层窗口进行操作.

## 相关

GroupActivate, GroupDeactivate, GroupClose

## 示例

按下热键可以遍历所有打开的 MSIE 窗口.

    ; 在脚本顶部的自动执行段:
    GroupAdd "MSIE", "ahk_class IEFrame" ; 只添加 Internet Explorer 窗口到该组.
    return ; 自动执行段的结束.

    ; 设置一个热键激活该组, 它会遍历
    ; 打开的所有 MSIE 窗口, 每次一个
    ; (即每次使用热键时激活一个窗口).
    Numpad1::GroupActivate "MSIE", "r"

按下热键, 每次访问一个 MS Outlook 2002 窗口.

    ; 在脚本顶部的自动执行段:
    SetTitleMatchMode 2
    GroupAdd "mail", "Message - Microsoft Word" ; This is for mails currently being composed
    GroupAdd "mail", "- Message (" ; 用于已打开的项目
    ; 需要附加文本以避免激活错误窗口:
    GroupAdd "mail", "Advanced Find", "Sear&ch for the word(s)"
    GroupAdd "mail", , "Recurrence:"
    GroupAdd "mail", "Reminder"
    GroupAdd "mail", "- Microsoft Outlook"
    return  ; 自动执行段的结束.

    ; 设置一个热键访问每个 Outlook 窗口(每次一个).
    Numpad5::GroupActivate "mail"

dftg