# StrSplit() [v1.1.13+]

使用指定的分隔符把一个字符串分解成多个子字符串并保存到数组中.

    Array := StrSplit(String , Delimiters, OmitChars, MaxParts)

## 参数

String

  要分割的字符串.

Delimiters

  如果此参数为空或省略, 那么将把输入字符串中的每个字符解析为单独的子字符串.

  否则, Delimiters 可以是单个字符串或字符串数组, 数组中的每个字符串都被用来确定子字符串之间的边界. 由于分隔符本身不被视为子字符串的一部分, 所以它们不会被包含在返回的数组中. 此外, 如果输入字符串中一对分隔符之间没有其他字符, 那么相应的数组元素会被置空.

  例如: `","` 将根据逗号每次出现的位置分割字符串. 同样地, 使用 `[A_Tab, A_Space]` 作为分隔符将在输入字符串中每次遇到空格或 tab 时创建一个新的数组元素.

OmitChars

  可选的字符列表(区分大小写), 用来从每个数组元素的开始和结尾部分移除这些字符. 例如, 如果 OmitChars 是 `" `t"`, 那么每个元素中开始和结尾部分(但中间的不会) 的空格和 tab 会被移除.

  如果 Delimiters 为空, 那么 OmitChars 表示需要从数组中排除的那些字符.

MaxParts [v1.1.28+]
  如果省略, 默认为 -1, 则表示 "没有限制". 否则, 请指定返回的子字符串的最大数目. 如果非零, 则字符串最多被分割 MaxParts-1 次, 并且在最后一个子字符串中返回字符串的其余部分(不包括任何前导或尾随的 OmitChars).

## 返回值

函数返回字符串数组(对象).

## 备注

空格和 tab 等空白字符会被保留, 除非它们被作为分隔符或包含在 OmitChars 中. 调用 Trim 函数可以把空格和 tab 从每个变量的两端移除. 例如: `MyArray1 := Trim(MyArray1)`.

要分割标准 CSV(逗号分隔值) 格式的字符串, 请使用解析循环, 因为它具有内置的 CSV 处理功能.

要在拆分字段之前以不同的顺序排列, 请使用 Sort 命令.

如果不需要把子字符串长时间的存储到内存中, 建议使用解析循环 -- 特别是当 String 非常大时, 在这种情况下, 将节省大量的内存. 例如:

    Colors := "red,green,blue"
    Loop, Parse, Colors, % ","
        MsgBox % "Color number " A_Index " is " A_LoopField

## 相关

StringSplit, 解析循环, 数组, Sort, SplitPath, InStr(), SubStr(), StrLen(), StringLower, StringUpper, StrReplace()

## 示例

将一个句子拆分成单词数组, 并报告第四个单词.

    TestString := "This is a test."
    word_array := StrSplit(TestString, A_Space, ".") ; 忽略句点.
    MsgBox % "The 4th word is " word_array[4]

将一个以逗号分隔的颜色列表拆分成一个子字符串数组, 并逐个遍历它们.

    colors := "red,green,blue"
    for index, color in StrSplit(colors, ",")
        MsgBox % "Color number " index " is " color

dftg