# #Warn [v1.0.95.00+]

启用或禁用可能产生错误的特定状况时的警告, 例如书写错误或缺少全局声明.

    #Warn WarningType, WarningMode

## 参数

WarningType

  要启用或禁用的警告类型. 如果省略, 默认为 All.

  UseUnsetLocal 或 UseUnsetGlobal: 在读取之前没有赋值或使用 VarSetCapacity() 初始化的变量时产生警告. 如果这种变量计划为空的, 则可以为它赋值空字符串来屏蔽这样的警告.

  根据用于局部和全局变量这种警告被分成两种单独的类型, 这是由于全局变量的持久, 脚本范围作用域的性质, 所以对不首先初始化而使用全局变量更常用. 因此, 一些脚本作者会希望在局部启用这种警告类型, 但禁用全局的.

      #Warn
      ;y := ""  ; 这样将屏蔽警告.
      x := y    ; y 还不含有值.

  UseEnv: 在自动使用环境变量代替空的脚本变量时产生警告. 当环境变量名意外地与脚本中使用的某个变量名相同时会发生这种情况. 这种警告会在访问变量时会产生, 但如果脚本使用了 #NoEnv(由于多种原因而推荐使用) 则可以避免.

      #Warn
      ;#NoEnv             ; 如果 "temp" 不是计划为环境变量则添加这行.
      ;EnvGet temp, TEMP  ; 这里将复制环境变量的值到脚本变量中.
      temp := ""          ; 不考虑这行, temp 仍然含有值.
      MsgBox % temp       ; 这里访问名称为 "TEMP" 的环境变量.

  LocalSameAsGlobal: 在脚本开始运行前, 为与全局变量名称相同的每个 未声明 局部变量显示警告. 这是用来避免在函数中由于忘记在访问全局变量前进行声明引起的错误. 如果变量确实为局部变量, 则可以用类似 `local x` 或 `static y` 这样的声明来屏蔽这种警告. 对于强制局部函数中变量, 不会显示此警告.

      #Warn
      g := 1
      ShowG() {       ; 即使从未调用这个函数也会显示警告.
          ;global g   ; <-- 访问全局变量时需要这行.
          MsgBox % g  ; 没有声明, 所以 "g" 是个空的局部变量.
      }

  ClassOverwrite [v1.1.27+]: 在脚本开始运行之前, 针对每个指定类变量的赋值显示警告. 例如, 如果 Box 是一个类, `box := new Box` 将会显示一个警告, 因为这会覆盖类(在超级全局变量中, Box ). 对于命令的输出变量也显示警告, 但 ByRef 参数不显示. 对于嵌套类或动态变量引用不会显示警告.

  Unreachable [v1.1.33+]: 在脚本开始运行之前, 为紧跟在同一嵌套级别的 `Return`, `Break`, `Continue`, `Throw`, `Goto` 或 `Exit` 的行显示一个警告, 除非该行是一个标签的目标. 虽然这并不能检测到所有的不可到达的代码, 但它能检测到常见的错误, 例如:

  - 将初始化代码(如赋值或 GroupAdd) 放在热键子程序之间, 而它应该在自动执行段.
  - 将 "多行" 热键子程序的第一行与热键标签放在同一行. 这样做会使它成为一个单行热键, 并有一个隐式的 `return` 防止任何后续行的执行. 同样, 在单行热键后放置 `return` 是多余的, 会引起警告.
  - 将一个子程序放在另一个子程序里面, 破坏了代码流.

  如果代码的目的是不可到达的 - 比如使用 `return` 来暂时禁用某块代码, 或者用注释的方式暂时禁用了某个热键或热串 - 可以考虑把不可到达的代码也注释掉. 另外, 也可以通过在第一行不可到达的代码上方定义一个标签来抑制警告.

  All: 应用指定的 WarningMode 支持的所有警告类型.

WarningMode

  表示警告方式的值. 如果省略, 默认为 MsgBox.

  MsgBox: 显示描述警告的消息框. 注意当这种消息框解除后, 脚本将照常继续.

  StdOut [v1.1.04+]: 把警告的描述以及相应的文件名和行号发送到 stdout(程序的标准输出流). 这样可以让类似 SciTE 的高级编辑器在不干扰脚本的同时捕获警告, 之后用户可以通过编辑器的控制面板跳转到各个出错行.

  OutputDebug: 把警告的描述发送到调试器显示出来. 如果没有活动的调试器, 则这个值没有效果. 想了解更多细节, 请参阅 OutputDebug.

  Off: 禁用指定 WarningType 的警告.

## 备注

默认情况下, 所有的警告都是关闭的.

无法在运行时启用或禁用警告, 这个设置是在脚本加载时确定的. 因此, 它在脚本中的位置是不重要的(并且与其他的指令一样, #Warn 不能根据条件执行).

然而, 多个 #Warn 指令的顺序是有意义的: 最近一次设置指定警告的指令决定了这种警告的模式. 所以, 例如下面的两个语句会启用除 UseEnv 之外的所有警告的组合效果:

    #Warn All
    #Warn UseEnv, Off

    EnvSet EnvVar, 1
    x := EnvVar       ; 由于没有使用 #NoEnv, 所以这句是正确的.
    x := NotAnEnvVar  ; 产生警告.

## 相关

局部变量和全局变量

## 示例

禁用所有警告. 这是默认设置.

    #Warn All, Off

启用每种警告并将它们显示到消息框中.

    #Warn

在赋值前使用局部变量时发送警告到 OutputDebug.

    #Warn UseUnsetLocal, OutputDebug

dftg