# FileCopy

复制一个或多个文件.

    FileCopy, SourcePattern, DestPattern , Overwrite

## 参数

SourcePattern

  单个文件或文件夹的名称或者通配符模式, 例如 C:\Temp\*.tmp. 如果未指定绝对路径, 则假定 SourcePattern 在 %A_WorkingDir% 中.

DestPattern

  目标的名称或模式, 如果未指定绝对路径, 则假定在 %A_WorkingDir% 中.

  如果星号存在, 则将文件名中的第一个星号(`*`) 替换为不包含其扩展名的源文件名, 而将最后一个句号(`.`) 后的第一个星号替换为源文件的扩展名. 如果有星号, 但省略了扩展名, 则使用源文件的扩展名.

  要执行简单地复制 -- 保留原来的文件名 -- 只需指定文件夹名, 如下面几乎等同的两个例子所示:

      FileCopy, C:\*.txt, C:\My Folder

      FileCopy, C:\*.txt, C:\My Folder\*.*

  目标目录必须已经存在. 如果 My Folder 不存在, 上面的第一个示例将使用 "My Folder" 作为目标文件名, 而第二个示例将不复制任何文件.

Overwrite

  此参数确定是否覆盖已存在的文件. 如果此参数为 1(true), 则该命令将覆盖现有文件. 如果省略或为 0(false), 则该命令不会覆盖现有文件.

  此参数可以为表达式, 甚至是计算结果为真或假的表达式(因为真和假内部分别保存为 1 和 0).

## 错误处理

[v1.1.04+]: 此命令失败时会抛出异常. 想了解更多信息, 请参阅运行时错误.

ErrorLevel 被设置为由于错误而无法复制的文件数, 否则为 0.

在这两种情况中, 如果源文件为单个文件(没有通配符) 且此文件不存在, 则 ErrorLevel 被置为 0. 要判断这种情况, 请在复制前对源文件使用 FileExist() 或 IfExist.

与 FileMove 不同, 复制一个文件来覆盖它自己总是会导致错误, 即使在改写模式生效的情况下.

如果找到了文件, 则 A_LastError 会被设置为 0(零) 或最近一次操作失败时调用操作系统 GetLastError() 函数的结果. 否则 A_LastError 包含了没有找到文件原因的错误码.

## 备注

FileCopy 只复制文件. 若要复制文件夹中的内容(它的所有文件和子文件夹, 而不复制文件夹本身), 请参照下面的示例部分. 若要复制单个文件夹(及其子文件夹), 请使用 FileCopyDir.

在遇到错误后操作仍会继续进行.

## 相关

FileMove, FileCopyDir, FileMoveDir, FileDelete

## 示例

复制文件并保留原来的文件名.

    FileCopy, C:\My Documents\List1.txt, D:\Main Backup\

复制文件到同一个文件夹并改变文件名.

    FileCopy, C:\My File.txt, C:\My File New.txt

复制文本文件到新位置并改变扩展名.

    FileCopy, C:\Folder1\*.txt, D:\New Folder\*.bkp

复制一个文件夹中所有文件和文件夹到另一个文件夹中.

    ErrorCount := CopyFilesAndFolders("C:\My Folder\*.*", "D:\Folder to receive all files & folders")
    if (ErrorCount != 0)
        MsgBox %ErrorCount% files/folders could not be copied.

    CopyFilesAndFolders(SourcePattern, DestinationFolder, DoOverwrite = false)
    ; 复制匹配 SourcePattern 的所有文件和文件夹到 DestinationFolder 文件夹中且
    ; 返回无法复制的文件/文件夹的数目.
    {
        ; 首先复制所有文件 (不是文件夹):
        FileCopy, %SourcePattern%, %DestinationFolder%, %DoOverwrite%
        ErrorCount := ErrorLevel
        ; 现在复制所有文件夹:
        Loop, %SourcePattern%, 2  ; 2 表示 "只获取文件夹".
        {
            FileCopyDir, %A_LoopFileFullPath%, %DestinationFolder%\%A_LoopFileName%, %DoOverwrite%
            ErrorCount += ErrorLevel
            if ErrorLevel  ; 报告每个出现问题的文件夹名称.
                MsgBox Could not copy %A_LoopFileFullPath% into %DestinationFolder%.
        }
        return ErrorCount
    }

dftg