# StatusBarWait

等待, 直到窗口的状态栏包含指定的字符串.

    StatusBarWait BarText, Timeout, Part#, WinTitle, WinText, Interval, ExcludeTitle, ExcludeText

## 参数

BarText

  类型: 字符串

  如果未设置或省略, 函数等待状态栏变成空白. 否则, 请指定函数所等待的文本或部分文本. 此文本是区分大小写的, 且匹配行为由 SetTitleMatchMode 决定, 类似于下面的 WinTitle.

  若要等待状态栏是否发生了 改变, 可以在循环中使用 StatusBarGetText, 或像本页底部的例子那样使用 RegEx.

Timeout

  类型: 整数或浮点数

  如果未设置或省略, 函数将会无限期等待. 否则, 请指定在超时前等待的秒数(可以是小数), 在这种情况下返回 0(false).

Part#

  类型: 整数

  如果未设置或省略, 默认为 1, 这部分通常包含了我们感兴趣的文本. 否则, 请指定要获取的状态栏那一部分的编号.

WinTitle, WinText, ExcludeTitle, ExcludeText

  类型: 字符串, 整数或对象

  如果这些都未设置或省略, 将使用上次找到的窗口. 否则, 为 WinTitle 指定窗口标题或其他条件, 来标识目标窗口, 和/或为 WinText 指定目标窗口的单个文本元素的子字符串(由包含的 Window Spy 实用程序显示). 如果 DetectHiddenText 已经打开, 则检测隐藏文本元素. 标题或文本包含 ExcludeTitle 或 ExcludeText 的窗口将不被考虑.

Interval

  类型: 整数

  如果未设置或省略, 默认为 50. 否则, 请指定此函数在等待时对状态栏进行检查的时间间隔(单位为毫秒).

## 返回值

类型: 整数(布尔值)

如果找到匹配, 该函数返回 1(true), 如果函数超时, 则返回 0(false).

## 错误处理

在以下任何一种情况下, 都会抛出异常:

- TargetError: 找不到目标窗口或不包含标准状态栏.
- OSError: 在发送 SB_GETPARTS 消息时出现了问题, 或者在 2000 ms 内没有收到回复.
- OSError: 在拥有状态栏的进程中无法分配内存.

## 备注

该函数尝试读取窗口中首个 标准 状态栏(Microsoft 通用控件: msctls_statusbar32). 某些程序使用它们自己的状态栏或微软通用控件的特殊版本. 不支持这样的状态栏.

在大多数时候, 与其在循环中使用 StatusBarGetText, 不如使用 StatusBarWait 来得有效率, 因为它避免重复调用 StatusBarGetText 所带来的开销.

StatusBarWait 在开始等待匹配前会确定它的目标窗口. 如果那个目标窗口关闭了, 那么此命令会停止等待, 即使存在另一个匹配指定 WinTitle 和 WinText 的窗口.

当函数处于等待状态时, 可以通过热键, 自定义菜单项或计时器启动新的线程.

窗口标题和文本是区分大小写的. 除非 DetectHiddenWindows 被打开, 否则不会检测隐藏窗口.

## 相关

StatusBarGetText, WinGetTitle, WinGetText, ControlGetText

## 示例

在现有的资源管理器/搜索窗口中输入新的搜索模式.

    if WinExist("Search Results") ; 设置上次找到的窗口以简化后面的代码.
    {
        WinActivate
        Send "{tab 2}!o*.txt{enter}"  ; 在搜索窗口中, 输入要搜索的模式.
        Sleep 400  ; 给状态栏时间, 等它改变为 "Searching".
        if StatusBarWait("found", 30)
            MsgBox "The search successfully completed."
        else
            MsgBox "The function timed out."
    }

等待活动窗口的状态栏发生变化.

    SetTitleMatchMode "RegEx"  ; 接受正则表达式, 以便在下面使用.
    if WinExist("A")  ; 设置上次找到的窗口为活动窗口(供下面使用).
    {
        OrigText := StatusBarGetText()
        StatusBarWait "^(?!^\Q" OrigText "\E$)"  ; 该正则表达式等待文本发生任何变化.
    }

dftg