# WinGetList

返回与指定条件匹配的所有现有窗口的唯一 ID 号.

    List := WinGetList(WinTitle, WinText, ExcludeTitle, ExcludeText)

## 参数

WinTitle, WinText, ExcludeTitle, ExcludeText

  类型: 字符串, 整数或对象

  如果这些都未设置或省略, 将使用上次找到的窗口. 否则, 为 WinTitle 指定窗口标题或其他条件, 来标识目标窗口, 和/或为 WinText 指定目标窗口的单个文本元素的子字符串(由包含的 Window Spy 实用程序显示). 如果 DetectHiddenText 已经打开, 则检测隐藏文本元素. 标题或文本包含 ExcludeTitle 或 ExcludeText 的窗口将不被考虑.

## 返回值

类型: 数组

此函数返回一个数组, 其中包含了与指定参数匹配的所有现有窗口的 窗口句柄(HWND). 如果没有匹配的窗口, 则返回一个空数组.

例如, 如果将返回值赋值给名为 `List` 的变量, 并且发现了两个匹配的窗口, 则 `List[1]` 包含第一个窗口的 ID, `List[2]` 包含第二个窗口的 ID, 而 `List.Length` 返回数字 2.

Windows 将按从顶部到底部的顺序检索(根据它们在桌面上的堆叠方式).

## 备注

要获取整个系统的所有窗口, 省略所有的四个标题/文本参数.

鼠标光标下的窗口的 ID 可以使用 MouseGetPos 来获取.

窗口标题和文本是区分大小写的. 除非 DetectHiddenWindows 被打开, 否则不会检测隐藏窗口.

## 相关

WinGetCount, 窗口函数, 控件函数

## 示例

访问整个系统中的所有窗口并显示它们的信息.

    ids := WinGetList(,, "Program Manager")
    for this_id in ids
    {
        WinActivate this_id
        this_class := WinGetClass(this_id)
        this_title := WinGetTitle(this_id)
        Result := MsgBox(
        (
            "Visiting All Windows
            " A_Index " of " ids.Length "
            ahk_id " this_id "
            ahk_class " this_class "
            " this_title "

            Continue?"
        ),, 4)
        if (Result = "No")
            break
    }

dftg